temp update (flakes are pain)

Hosts/hertog-laptop/packages.nix

@@ -1,6 +1,8 @@
 { config, pkgs, inputs, ... }:
 let
   mini-text = pkgs.callPackage ../../Programs/MiniText { };
+  hyperplane = pkgs.callPackage ../../Programs/Hyperplane { };
+  cosmic-terminal = pkgs.callPackage ../../Programs/Cosmic-Terminal {};
 in
 {
   # Allow unfree packages
@@ -28,7 +30,9 @@ in
       warp
       tor-browser-bundle-bin
       pamixer
+      hyperplane
       mini-text
+      cosmic-terminal
     ];
   };
 }

Programs/Cosmic-Terminal/default.nix

@@ -0,0 +1,97 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  rust,
+  rustPlatform,
+  cmake,
+  makeBinaryWrapper,
+  cosmic-icons,
+  just,
+  pkg-config,
+  libxkbcommon,
+  glib,
+  gtk3,
+  libinput,
+  fontconfig,
+  freetype,
+  wayland,
+  xorg
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "cosmic-term";
+  version = "unstable-2023-12-26";
+
+  src = fetchFromGitHub {
+    owner = "pop-os";
+    repo = pname;
+    rev = "bf3f507fdd73a06ab1f9b199a98dca6988aafec2";
+    hash = "sha256-c5RNrC0AZvz+O3nj7VvMQuA/U0sgxZCVHn+cc+4pIN8=";
+  };
+
+  cargoLock = {
+    lockFile = ./Cargo.lock;
+    outputHashes = {
+      "accesskit-0.11.0" = "sha256-xVhe6adUb8VmwIKKjHxwCwOo5Y1p3Or3ylcJJdLDrrE=";
+      "atomicwrites-0.4.2" = "sha256-QZSuGPrJXh+svMeFWqAXoqZQxLq/WfIiamqvjJNVhxA=";
+      "cosmic-config-0.1.0" = "sha256-V371fmSmLIwUxtx6w+C55cBJ8oyYgN86r3FZ8rGBLEs=";
+      "cosmic-text-0.10.0" = "sha256-/4Hg+7R0LRF4paXIREkMOTtbQ1xgONym5nKb/TuyeD4=";
+      "glyphon-0.3.0" = "sha256-T7hvqtR3zi9wNemFrPPGakq2vEraLpnPkN7umtumwVg=";
+      "sctk-adwaita-0.5.4" = "sha256-yK0F2w/0nxyKrSiHZbx7+aPNY2vlFs7s8nu/COp2KqQ=";
+      "softbuffer-0.3.3" = "sha256-eKYFVr6C1+X6ulidHIu9SP591rJxStxwL9uMiqnXx4k=";
+      "smithay-client-toolkit-0.16.1" = "sha256-z7EZThbh7YmKzAACv181zaEZmWxTrMkFRzP0nfsHK6c=";
+      "taffy-0.3.11" = "sha256-SCx9GEIJjWdoNVyq+RZAGn0N71qraKZxf9ZWhvyzLaI=";
+      "winit-0.28.6" = "sha256-FhW6d2XnXCGJUMoT9EMQew9/OPXiehy/JraeCiVd76M=";
+    };
+  };
+  
+  postPatch = ''
+    substituteInPlace justfile --replace '#!/usr/bin/env' "#!$(command -v env)"
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    just
+    pkg-config
+    makeBinaryWrapper
+  ];
+  buildInputs = [
+    libxkbcommon
+    xorg.libX11
+    libinput
+    fontconfig
+    freetype
+    wayland
+    glib
+    gtk3
+  ];
+
+  dontUseJustBuild = true;
+
+  justFlags = [
+    "--set"
+    "prefix"
+    (placeholder "out")
+    "--set"
+    "bin-src"
+    "target/${
+      rust.lib.toRustTargetSpecShort stdenv.hostPlatform
+    }/release/cosmic-term"
+  ];
+
+  # LD_LIBRARY_PATH can be removed once tiny-xlib is bumped above 0.2.2
+  postInstall = ''
+    wrapProgram "$out/bin/${pname}" \
+      --suffix XDG_DATA_DIRS : "${cosmic-icons}/share" \
+      --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ xorg.libX11 wayland libxkbcommon ]}
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/pop-os/cosmic-term";
+    description = "Terminal for the COSMIC Desktop Environment";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ ahoneybun ];
+    platforms = platforms.linux;
+  };
+}

Programs/Hyperplane/default.nix

@@ -0,0 +1,53 @@
+{ blueprint-compiler
+, desktop-file-utils
+, fetchFromGitHub
+, gobject-introspection
+, lib
+, libadwaita
+, meson
+, ninja
+, python3
+, stdenv
+, wrapGAppsHook4
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hyperplane";
+  owner = "kra-mo";
+  version = "0.1.0";
+
+  src = fetchFromGitHub {
+    owner = "${finalAttrs.owner}";
+    repo = "${finalAttrs.pname}";
+    rev = "v${finalAttrs.version}-beta";
+    hash = "sha256-ShpB6Etew1+naLyxHGhHCcyD95QlurWQ+S9/zbMXYrw=";
+  };
+
+  buildInputs = [
+    libadwaita
+    (python3.withPackages (p: with p; [
+      pillow
+      pygobject3
+      pyyaml
+      requests
+    ]))
+  ];
+
+  nativeBuildInputs = [
+    blueprint-compiler
+    desktop-file-utils
+    gobject-introspection
+    meson
+    ninja
+    wrapGAppsHook4
+  ];
+
+  meta = with lib; {
+    inherit (src.meta) homepage;
+    description = "A non-hierachical file manager";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ hertog ];
+    license = licenses.gpl3;
+    changelog = "https://github.com/${finalAttrs.owner}/${finalAttrs.pname}/releases/tag/${finalAttrs.version}";
+  };
+})

Programs/RustyThingy/default.nix

@@ -0,0 +1,67 @@
+{ lib
+, rustPlatform
+, fetchFromGitea
+, makeWrapper
+, pkg-config
+, stdenv
+, alsa-lib
+, libxkbcommon
+, udev
+, vulkan-loader
+, wayland
+, xorg
+, darwin
+}:
+
+rustPlatform.buildRustPackage {
+  pname = "hertog-game";
+  version = "0.1.0";
+
+  src = fetchFromGitea {
+    domain = "git.saragerretsen.nl";
+    owner = "Hertog";
+    repo = "RustThingy";
+    rev = "Development";
+    hash = "sha256-ji/HCpADrblMlTHU2V+AdtQz6uHNGbw4bEJilr+cMwU=";
+  };
+
+  cargoHash = "sha256-pSaJ9OTIgztWXVshB5Wch/dbOXI3t3g4jcrIcfBvyoQ=";
+  
+  nativeBuildInputs = [
+    makeWrapper
+    pkg-config
+  ] ++ lib.optionals stdenv.isLinux [
+    vulkan-loader
+  ];
+
+  buildInputs = [
+  ] ++ lib.optionals stdenv.isLinux [
+    alsa-lib
+    libxkbcommon
+    udev
+    vulkan-loader
+    wayland
+    xorg.libX11
+    xorg.libXcursor
+    xorg.libXi
+    xorg.libXrandr
+  ] ++ lib.optionals stdenv.isDarwin [
+    darwin.apple_sdk_11_0.frameworks.Cocoa
+    rustPlatform.bindgenHook
+  ];
+
+  postInstall = ''
+    mkdir $out/bin/assets
+    mkdir $out/bin/data
+    cp -r assets $out/bin/
+    cp -r data $out/bin/
+  '';
+
+  meta = with lib; {
+    description = "A W.I.P. bevy-engine game";
+    homepage = "https://git.saragerretsen.nl/Hertog/RustThingy";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ hertog ];
+    platforms = platforms.unix;
+  };
+}

Users/Hertog/dconf.nix

@@ -1,9 +1,8 @@
-{ config, ... }:
+{ conf, ... }:
 
 {
-  dconf.settings = {
+  dconf = {
-    "org/gnome/desktop/interface" = {
+    enable = true;
-      color-scheme = "prefer-dark";
+    settings."org/gnome/desktop/interface".color-scheme = "prefer-dark";
-    };
   };
 }

Users/Hertog/homeFull.nix

@@ -1,4 +1,7 @@
 { config, pkgs, ... }:
+let
+  hertog-game = pkgs.callPackage ../../Programs/RustyThingy { };
+in
 {
   home = {
     stateVersion = "23.05";
@@ -21,12 +24,15 @@
       # Security
       keepassxc
       # Entertainment
+      hertog-game
+      jumpy
       cartridges
       prismlauncher-qt5
       qFlipper
       protonup-qt
       stremio
       spotify
+      r2modman
       # Art
       inkscape
       gimp